AC_INIT(src/dancespy.cc)
AC_CANONICAL_SYSTEM
AC_ARG_VAR(PKG_CONFIG_PATH, [additional paths for pkg-config])

dnl Change this to reflect the current release before distributing.
MAJOR_VERSION=1
MINOR_VERSION=0
MICRO_VERSION=1

VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION
VERSION_INFO=`expr $MAJOR_VERSION + $MINOR_VERSION`:$MICRO_VERSION:$MINOR_VERSION

AM_INIT_AUTOMAKE(dancespy, $VERSION)
AM_CONFIG_HEADER(config.h)

AC_SUBST(MAJOR_VERSION)
AC_SUBST(MINOR_VERSION)
AC_SUBST(MICRO_VERSION)
AC_SUBST(VERSION)
AC_SUBST(VERSION_INFO)

PACKAGEUPPER=`echo "$PACKAGE" | tr "[a-z]" "[A-Z]"`
AC_SUBST(PACKAGEUPPER)

AM_MAINTAINER_MODE

AC_EXEEXT

AC_PROG_CC
AC_PROG_CPP
AC_PROG_CXX
AC_PROG_INSTALL
AC_LIBTOOL_WIN32_DLL
AM_PROG_LIBTOOL

# Capture m4 path ala GNOME.
AC_CONFIG_MACRO_DIR([m4])
AC_SUBST([ACLOCAL_AMFLAGS], ["-I m4 \${ACLOCAL_FLAGS}"])

AC_CHECK_FUNCS(localtime_r gmtime_r)

AX_BOOST

# Additional platform libs.  Note that the customized libnids win32 
# port needs built on Windows.
case "$host" in
  *mingw32*)
    WINSOCK_CPPFLAGS=""
    WINSOCK_LIBS="-lws2_32"
    PCAP_CPPFLAGS=""
    PCAP_LIBS="-lwpcap"
    NIDS_CPPFLAGS="-I${top_srcdir}/nids/include"
    NIDS_LIBS="${top_srcdir}/nids/src/libnids.la"
  ;;
esac

# Detect pcap.
oldlibs="$LIBS"
oldcppflags="$CPPFLAGS"
LIBS="$oldlibs -lpcap"
AC_MSG_CHECKING([for libpcap])
AC_TRY_LINK([
#include <pcap.h>
  ], [
pcap_close((pcap_t *) 0);
  ],
  [ac_cv_var_pcap=yes],
  [ac_cv_var_pcap=no]
)
if test x"$ac_cv_var_pcap" = x"yes"; then
  AC_MSG_RESULT([yes])
  PCAP_LIBS="-lpcap"
else
  AC_MSG_RESULT([no])

  # On Windows, we can use winpcap.
  case "$host" in
    *mingw32*)
      LIBS="$oldlibs -lws2_32 -lwpcap"
      AC_MSG_CHECKING([for winpcap])
      AC_TRY_LINK([
#include <pcap.h>
        ], [
pcap_close((pcap_t *) 0);
        ],
        [ac_cv_var_winpcap=yes],
        [ac_cv_var_winpcap=no]
      )
      if test x"$ac_cv_var_winpcap" = x"yes"; then
        AC_MSG_RESULT([yes])
        PCAP_LIBS="-lws2_32 -lwpcap"
      else
        AC_MSG_RESULT([no])
        AC_MSG_ERROR([libpcap or winpcap is required])
      fi
      ;;
    *)
      AC_MSG_ERROR([libpcap is required])
      ;;
  esac
fi
LIBS=$oldlibs
CPPFLAGS=$oldcppflags

# Detect nids.
oldlibs="$LIBS"
oldcppflags="$CPPFLAGS"
LIBS="$oldlibs -lnids"
AC_MSG_CHECKING([for libnids])
AC_TRY_LINK([
#include <nids.h>
  ], [
nids_run();
  ],
  [ac_cv_var_nids=yes],
  [ac_cv_var_nids=no]
)
if test x"$ac_cv_var_nids" = x"yes"; then
  AC_MSG_RESULT([yes])
  NIDS_CPPFLAGS=""
  NIDS_LIBS="-lnids"
else

  # On Windows, we can use our bundled, heavily modified, libnids win32 
  # port.
  case "$host" in
    *mingw32*)
      AC_MSG_RESULT([no (will use bundled libnids)])
      NIDS_CPPFLAGS="-I\${top_srcdir}/nids/include"
      NIDS_LIBS="\${top_srcdir}/nids/src/libnids.la"
      ac_cv_var_bundled_nids=yes
      ;;
    *)
      AC_MSG_RESULT([no])
      AC_MSG_ERROR([libnids is required])
      ;;
  esac
fi
LIBS=$oldlibs
CPPFLAGS=$oldcppflags
AM_CONDITIONAL(BUNDLED_NIDS, test x"$ac_cv_var_bundled_nids"  = x"yes")

# Detect pthreads.
oldlibs="$LIBS"
oldcppflags="$CPPFLAGS"
LIBS="$oldlibs -lpthread"
AC_MSG_CHECKING([for pthreads])
AC_TRY_COMPILE([
#include <pthread.h>
  ], [
pthread_self();
  ],
  [ac_cv_var_pthreads=yes],
  [ac_cv_var_pthreads=no]
)
if test x"$ac_cv_var_pthreads" = x"yes"; then
  AC_MSG_RESULT([yes])
  PTHREAD_CPPFLAGS=""
  PTHREAD_LIBS="-lpthread"
else
  AC_MSG_ERROR([pthreads not found and are required])
fi
LIBS=$oldlibs
CPPFLAGS=$oldcppflags

DANCESPY_CPPFLAGS="$BOOST_CPPFLAGS $PLATFORM_CPPFLAGS $PCAP_CPPFLAGS $NIDS_CPPFLAGS $PTHREAD_CPPFLAGS"
DANCESPY_LIBS="$BOOST_LDFLAGS $PLATFORM_LIBS $PCAP_LIBS $NIDS_LIBS $PTHREAD_LIBS"

AC_SUBST(DANCESPY_CPPFLAGS)
AC_SUBST(DANCESPY_LIBS)

AC_CONFIG_FILES([\
  Makefile \
  src/Makefile \
  m4/Makefile \
  nids/Makefile \
  nids/src/Makefile \
  nids/include/Makefile \
  nids/include/netinet/Makefile \
  nids/include/net/Makefile \
])

AC_OUTPUT